SYSTEM KAP scripts on a Canon A570is

Frequently asked questions
rrllewellyn
Posts: 3
Joined: Fri May 27, 2016 11:08 pm

SYSTEM KAP scripts on a Canon A570is

Postby rrllewellyn » Wed Jun 01, 2016 1:25 pm

I have enjoyed using SDM for my KAP activities. I have downloaded SDM version 2.1; however, I seem to be overlooking some camera setting or parameter setting for my Canon A570is. I start the camera in PLAYBACK; the SYSTEM KAP script loads and begins, but then the entire camera turns off just after extending the lens. The SYSTEM KAP script works fine with my Canon S95. Any suggestions about what I am overlooking? The EASYMODE scripts for timelapse work fine.

mich2e
Posts: 3
Joined: Thu May 26, 2016 7:12 am

Re: SYSTEM KAP scripts on a Canon A570is

Postby mich2e » Thu Jun 02, 2016 7:55 am

Hi rrllewellyn ,
by turning off, do you mean the camera is really shutting down (including lens retract) or camera freezes ?
Any info displayed or warning beep before closing ?
Actually I did not explore so much this script as my S100 hardly started in playback mode, but apparently the only reason for shutting down in script is pressing menu key (apart from having completed cycles of pics).
Maybe you could also try the kap2.txt script in user script folder to check wether you could use it. I can easily adapt this one to your needs, as i already realize that many texts could be translated in english ;-)

rrllewellyn
Posts: 3
Joined: Fri May 27, 2016 11:08 pm

Re: SYSTEM KAP scripts on a Canon A570is

Postby rrllewellyn » Thu Jun 09, 2016 2:56 am

Thanks for picking up this tread and making some suggestions. It appears that that camera simply shuts all functions down--the green power on light is off, when the camera is restarted all previous settings have been canceled; however the lens does not retract. I have been successful in testing the KAP1 and KAP2 scripts in the USER SCRIPTS mode. I am still open for comments about how to get the multiple KAP SYSTEM SCRIPTS to work.

mich2e
Posts: 3
Joined: Thu May 26, 2016 7:12 am

Re: SYSTEM KAP scripts on a Canon A570is

Postby mich2e » Fri Jun 10, 2016 5:06 pm

I"ve modified sligthly the autokap script to make it more usable.

Code: Select all

@title AutoKAP 5
rem autokap  shoot
@param d shoot interval sec
@default d 5
@param e total images
@default e 400
@param j xml 0/1/2
@default j 2
@param k screen 0-10 pics /10
@values 0 1 2 3 4 5 6 7 8 9 10
@default k 4
@param l led  0 - 10 pics /10
@default l 0
@range l 0 10
@param o iso max
@default o 250
@param p pause (0 off N pics)
@default p 0
@param q pause duration ( sec )
@default q 10
// reshoot if focus is not at infinity
@param r reshoot O/N 0/1
@default r 0
@param s first delay seconds
@default s 2
@param t shutter speed
@default t 800
@param v EV/3 correction
@default v 0
@range v -6 to +6
@param x zoom move every x pics
@default x 3
@param y zoom step change
@default y 3
@param z zoom positions
@default z 3
set_config_value 125 666 // restart on script error
sdm_console_line_length 42
console_position 9 30
big_zoom_display_off
rem save xml files
 set_config_value 79 j
 sleep 500
 i = 0
 set_max_iso_to o
 //  exposure compensation
set_shoot_fast_param 0 v
L = 1
 line L "~1! Autokap Init..."
   line (L+1) "~2 ", e, "pics"
   line (L+2) "~2 interval " , d, "sec"
   line (L+3) "~2 vit 1/";t, "iso:"o
   if p > 0 then line (L+4) "~1 pause "; q "sec /", p,"pics" 
   if k = 10 then
      line (L+5) "~1 LCD ON"
      else
      line (L+5) "~1 mode LCD ", k, "vues /10"
   endif
   if x > 0 then
      line (L+6) "~1 Zoom :", z, "pos/", x; "pics",
      else
      line (L+6) "~1 NO Zoom :"
   endif   
   if l > 0 then
      line (L+7) "~1 LED ",l;"/10 vues"
      else
      line (L+7) "~1 NO LED "
   endif   
   if v <> 0 then line (L+8) "~1 EV correc ", v
   line (L+9) "~1 press a key to start..."
  wait_click 5000
  set_config_value 300 40
  cls
  if s > 5 then
     playback_mode
   A = get_day_seconds
   do
      B = get_day_seconds-A
      line (L+3)  " pause " , s-B
   until B > s
   record_mode
   sleep_for_seconds 3
endif
rem passage Autofocus
 line (L+2)  "~2    AutoFocus"
 mf_off
 sleep 200

:shoot
   cls
   do
      i = i +1
      line (L+1)  "~2@# image " , i , "/", e
      if p > 0 then line  (L+4)  "~1 next pause ", (p-(i%p)), "pics"
      set_config_value 301 415003
      shoot_fast_at 1/t,b
      D = get_focus
      line (L+1) "~2@# Tv = " ,message, av_value
      if i%10 < l then
         set_led 9 1
         sleep 25
         set_led 9 0
      endif   
      if D > 0 and r = 1 then
         line L "!   Distance MAP = ", D, " Reshooot"
         manual_focus_on
         I = lock_focus_at_infinity
         set_config_value 301 44
         shoot_fast_at 1/t
         cls
         sleep 500
         manual_focus_off
         sleep 50
         set_config_value 303 1
      endif
      Q = get_tv96
      gosub "interval"
      if x > 0 then gosub "zoom"
      if p > 0 and i%p = 0 then gosub "pause"
      if i%5 = 2 then gosub "lcd"      
   until i > e
shut_down
end

:interval
      A = get_day_seconds
      do
         B = (get_day_seconds - A)
         line (L+7) "~2@!"; (d-B), "s"
      until B >= (d)
      return


:lcd
   cls
   line (L+1)  "~2 gestion LCD..."
   line (L+2) "~2 UP ON, Down OFF, LEFT alt"
   line (L+5)  " k , A%10 = ", k, A%10
   warning
   wait_click 1500
   m = is_key "down"
   l = is_key "up"
   n = is_key "left"
   if n = 1 then k = 3
   if l = 1 then k = 10
   if m = 1 then
      k=0
      beep
   endif
   line (L+5)  " k , A%10 = ", k, A%10
   sleep 1000
   if i%10 < k then
      turn_lcd_power_on
      else
      turn_lcd_power_off
   endif   
   cls
   return
   
:zoom
    if i%x = 0 then set_zoom_rel y
    sleep 500
    if i%(x*z) = 0 then
      set_zoom 0
      sleep 1000
      click "zoom_out"
      sleep 500
    endif
     return
    
  :pause
      playback_mode
      sleep 2000
      turn_lcd_power_off
      sleep_for_seconds q-3
      record_mode
      sleep 2000
      set_config_value 79 j
      turn_lcd_power_on
      capture_mode 3
      shutter_speed 1/t
      set_shoot_fast_param 0 v
      sleep 500
   return


I'm also joining a short explanation about parameters.

Code: Select all

Autokap
this script allows setting many parameters for autokap.
in script parameters:
d is interval duration between shots
e is total number of pics
j defines if xml are recorded with pictures (2) within xml folder (1) not recorded (0) default 2
k sets the duration of screen being on/off. if k = 0, the screen is off, otherwise the screen is on k view out of 10. if k = 10 then the screen is always on.
l is the frequence of emittign the AF led out of 10 views. 0 = never, 10 always. this allows to see if the camera is shooting
o is maximum iso
p is optional; defines a pause every p pictures. if p=0 = no pause. during pause the camera goes to playback mode to allow lens to retract.
q = pause duration in seconds
r is an option to reshoot if focus is not set at infinity: typically when the kite line is in the frame, the camera may focus on the line. if r = 1 then the camera tries to reshoot with focus set at infinity.
s is the "time to air" delay = delay before 1st picture
t = preferred shutter speed (default 1/800)
v = Exposure value correction
x = frequence of zoom change: the zomm changes every x pictures. If x = 0, no zoom change.
y = zoom step variation amplitude. defines the change step of zoom. (depends on the camera)
z = number of zoom positions used

script functions
the script uses a shoot_fast command that optimize shutter speed according to defined max iso value.
you can define after start if you want to switch screen on/off. every five pics the camera will beep (warning beep). at this moment if the "up" key is pressed the camera will turn screen on. if "down" is pressed the lcs will blank, if left is pressed, screen will be on for 3 pics / 10 pics
LED can be activated to control if the camera shoots

Hope you can use it

WBL
Posts: 20
Joined: Tue May 24, 2016 10:58 am

Re: SYSTEM KAP scripts on a Canon A570is

Postby WBL » Fri Jun 10, 2016 6:48 pm

no need to use dropbox to upload files since you can not guarantee that these file are still accessible in 1 or 2 years - this is possible direct in this forum.
(did remove the dropbox links and added the files direct)

Werner

rrllewellyn
Posts: 3
Joined: Fri May 27, 2016 11:08 pm

Re: SYSTEM KAP scripts on a Canon A570is

Postby rrllewellyn » Mon Jun 27, 2016 2:11 pm

Update: I have tried every combination of possible camera and SDM settings and my Canon A570is still does not support the SYSTEM KAP scripts. I still believe I am overlooking some important setting or sequence in activating the program. As reported above the USER KAP scripts work very nicely. Anyone reading this forum -- have you had a similar experience?

RRL


Return to “Q&A”

Who is online

Users browsing this forum: No registered users and 1 guest